Created
August 2, 2017 17:32
-
-
Save aesnyder/891d13fd3d900969b45b3ca0d53fc848 to your computer and use it in GitHub Desktop.
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
| # vim:ft=zsh ts=2 sw=2 sts=2 | |
| # | |
| # snyder.zsh-theme | |
| # a simplified agnoster theme with directory in right prompt | |
| # | |
| # | |
| # based off of agnoster's Theme - https://gist.github.com/3712874 | |
| # A Powerline-inspired theme for ZSH | |
| # | |
| CURRENT_BG='NONE' | |
| # Special Powerline characters | |
| () { | |
| local LC_ALL="" LC_CTYPE="en_US.UTF-8" | |
| SEGMENT_SEPARATOR=$'\ue0b0' | |
| } | |
| # Begin a segment | |
| # Takes two arguments, background and foreground. Both can be omitted, | |
| # rendering default background/foreground. | |
| prompt_segment() { | |
| local bg fg | |
| [[ -n $1 ]] && bg="%K{$1}" || bg="%k" | |
| [[ -n $2 ]] && fg="%F{$2}" || fg="%f" | |
| if [[ $CURRENT_BG != 'NONE' && $1 != $CURRENT_BG ]]; then | |
| echo -n " %{$bg%F{$CURRENT_BG}%}$SEGMENT_SEPARATOR%{$fg%} " | |
| else | |
| echo -n "%{$bg%}%{$fg%} " | |
| fi | |
| CURRENT_BG=$1 | |
| [[ -n $3 ]] && echo -n $3 | |
| } | |
| # End the prompt, closing any open segments | |
| prompt_end() { | |
| if [[ -n $CURRENT_BG ]]; then | |
| if $(git rev-parse --is-inside-work-tree >/dev/null 2>&1); then | |
| echo -n " %{%k%F{$CURRENT_BG}%}$SEGMENT_SEPARATOR" | |
| else | |
| echo -n " %{%k%F{$CURRENT_BG}%}" | |
| fi | |
| else | |
| echo -n "%{%k%}" | |
| fi | |
| echo -n "%{%f%}" | |
| CURRENT_BG='' | |
| } | |
| ### Prompt components | |
| # Each component will draw itself, and hide itself if no information needs to be shown | |
| # Git: branch/detached head, dirty status | |
| prompt_git() { | |
| local PL_BRANCH_CHAR | |
| () { | |
| local LC_ALL="" LC_CTYPE="en_US.UTF-8" | |
| PL_BRANCH_CHAR=$'\ue0a0' # | |
| } | |
| local ref dirty mode repo_path | |
| repo_path=$(git rev-parse --git-dir 2>/dev/null) | |
| if $(git rev-parse --is-inside-work-tree >/dev/null 2>&1); then | |
| dirty=$(parse_git_dirty) | |
| ref=$(git symbolic-ref HEAD 2> /dev/null) || ref="➦ $(git rev-parse --short HEAD 2> /dev/null)" | |
| if [[ -n $dirty ]]; then | |
| prompt_segment yellow black | |
| else | |
| prompt_segment green black | |
| fi | |
| if [[ -e "${repo_path}/BISECT_LOG" ]]; then | |
| mode=" <B>" | |
| elif [[ -e "${repo_path}/MERGE_HEAD" ]]; then | |
| mode=" >M<" | |
| elif [[ -e "${repo_path}/rebase" || -e "${repo_path}/rebase-apply" || -e "${repo_path}/rebase-merge" || -e "${repo_path}/../.dotest" ]]; then | |
| mode=" >R>" | |
| fi | |
| setopt promptsubst | |
| autoload -Uz vcs_info | |
| zstyle ':vcs_info:*' enable git | |
| zstyle ':vcs_info:*' get-revision true | |
| zstyle ':vcs_info:*' check-for-changes true | |
| zstyle ':vcs_info:*' stagedstr '✚' | |
| zstyle ':vcs_info:*' unstagedstr '●' | |
| zstyle ':vcs_info:*' formats ' %u%c' | |
| zstyle ':vcs_info:*' actionformats ' %u%c' | |
| vcs_info | |
| echo -n "${ref/refs\/heads\//$PL_BRANCH_CHAR }${vcs_info_msg_0_%% }${mode}" | |
| fi | |
| } | |
| prompt_hg() { | |
| local rev status | |
| if $(hg id >/dev/null 2>&1); then | |
| if $(hg prompt >/dev/null 2>&1); then | |
| if [[ $(hg prompt "{status|unknown}") = "?" ]]; then | |
| # if files are not added | |
| prompt_segment red white | |
| st='±' | |
| elif [[ -n $(hg prompt "{status|modified}") ]]; then | |
| # if any modification | |
| prompt_segment yellow black | |
| st='±' | |
| else | |
| # if working copy is clean | |
| prompt_segment green black | |
| fi | |
| echo -n $(hg prompt "☿ {rev}@{branch}") $st | |
| else | |
| st="" | |
| rev=$(hg id -n 2>/dev/null | sed 's/[^-0-9]//g') | |
| branch=$(hg id -b 2>/dev/null) | |
| if `hg st | grep -q "^\?"`; then | |
| prompt_segment red black | |
| st='±' | |
| elif `hg st | grep -q "^[MA]"`; then | |
| prompt_segment yellow black | |
| st='±' | |
| else | |
| prompt_segment green black | |
| fi | |
| echo -n "☿ $rev@$branch" $st | |
| fi | |
| fi | |
| } | |
| ## Main prompt | |
| build_prompt() { | |
| RETVAL=$? | |
| prompt_git | |
| prompt_hg | |
| prompt_end | |
| } | |
| function get_pwd(){ | |
| git_root=$PWD | |
| while [[ $git_root != / && ! -e $git_root/.git ]]; do | |
| git_root=$git_root:h | |
| done | |
| if [[ $git_root = / ]]; then | |
| unset git_root | |
| prompt_short_dir=%~ | |
| else | |
| parent=${git_root%\/*} | |
| prompt_short_dir=${PWD#$parent/} | |
| fi | |
| echo $prompt_short_dir | |
| } | |
| PROMPT='%{%f%b%k%}$(build_prompt) ' | |
| RPROMPT='$(get_pwd)' |
Note, you will need a powerline compatible font: they are available here: https://github.com/powerline/fonts
I'm using Deja Vu Sans.
Sign up for free
to join this conversation on GitHub.
Already have an account?
Sign in to comment
In repo:
Out of repo:
Basically a slimmed down version of agnoster on the left with a right prompt that shows the current repo name or working directory.